# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit autotools ltprune libtool toolchain-funcs

DESCRIPTION="BitTorrent library written in C++ for *nix"
HOMEPAGE="https://rakshasa.github.io/rtorrent/"
SRC_URI="
	http://rtorrent.net/downloads/${P}.tar.gz
	ps? (
		https://raw.githubusercontent.com/pyroscope/rtorrent-ps/master/patches/lt-base-cppunit-pkgconfig.patch
		https://raw.githubusercontent.com/pyroscope/rtorrent-ps/master/patches/lt-ps-honor_system_file_allocate_all.patch
		https://raw.githubusercontent.com/pyroscope/rtorrent-ps/master/patches/lt-ps-log_open_file-reopen_all.patch
	)"

LICENSE="GPL-2"

# The README says that the library ABI is not yet stable and dependencies on
# the library should be an explicit, syncronized version until the library
# has had more time to mature. Until it matures we should not include a soname
# subslot.
SLOT="0"

KEYWORDS="amd64 ~arm ~hppa ~ia64 ppc ppc64 ~sparc x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
IUSE="debug ipv6 libressl ssl test +ps"

RDEPEND="
	sys-libs/zlib
	dev-libs/libsigc++:2
	ssl? (
	    !libressl? ( dev-libs/openssl:0= )
	    libressl? ( dev-libs/libressl:= )
	)"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	test? ( dev-util/cppunit )"

src_prepare() {
	if use ps ; then
		list=(
			"${DISTDIR}"/lt-base-cppunit-pkgconfig.patch
			"${DISTDIR}"/lt-ps-honor_system_file_allocate_all.patch
			"${DISTDIR}"/lt-ps-log_open_file-reopen_all.patch
		)
		eapply "${list[@]}"
	fi
	eapply_user
	eautoreconf
}

src_configure() {
	# bug 518582
	local disable_instrumentation
	echo -e "#include <inttypes.h>\nint main(){ int64_t var = 7; __sync_add_and_fetch(&var, 1); return 0;}" > "${T}/sync_add_and_fetch.c" || die
	$(tc-getCC) ${CFLAGS} -o /dev/null -x c "${T}/sync_add_and_fetch.c" >/dev/null 2>&1
	if [[ $? -ne 0 ]]; then
		disable_instrumentation="--disable-instrumentation"
	fi

	# configure needs bash or script bombs out on some null shift, bug #291229
	CONFIG_SHELL=${BASH} econf \
		--enable-aligned \
		$(use_enable debug) \
		$(use_enable ipv6) \
		$(use_enable ssl openssl) \
		${disable_instrumentation} \
		--with-posix-fallocate
}

src_install() {
	default

	prune_libtool_files --all
}