# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
# This is a modified version of roundcube ebuild from webapps-experimental repository
inherit webapp depend.php depend.apache

MY_PN="${PN}mail"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="A browser-based multilingual IMAP client using AJAX"
HOMEPAGE="http://www.roundcube.net"
SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}.tar.gz"

# roundcube is GPL-licensed, the rest of the licenses here are
# for bundled PEAR components, googiespell and utf8.class.php
LICENSE="GPL-2 BSD PHP-2.02 PHP-3 MIT public-domain"
KEYWORDS="~amd64 ~x86"
IUSE="ldap mysql postgres sqlite ssl spell"

RDEPEND="dev-php/PEAR-PEAR"
need_httpd_cgi
need_php_httpd

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	local flags="crypt iconv imap pcre session socket unicode"
	use ldap && flags="${flags} ldap"
	use ssl && flags="${flags} ssl"
	use spell && flags="${flags} curl ssl"

	# check for required PHP features
	# add some warnings about optional functionality
	use ldap || ewarn "PHP with USE=\"ldap\" is required for using LDAP addressbooks."
	use ssl || ewarn "PHP with USE=\"ssl\" is required for IMAPS/STMPS functionality."
	use spell || ewarn "PHP with USE=\"curl ssl\" required for spellchecker functionality."

	webapp_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"/config
	mv db.inc.php.dist db.inc.php
	mv main.inc.php.dist main.inc.php
}

src_install () {
	webapp_src_preinst
	dodoc CHANGELOG INSTALL README UPGRADING

	cp -R [[:lower:]]* SQL "${D}/${MY_HTDOCSDIR}"

	webapp_serverowned "${MY_HTDOCSDIR}"/logs
	webapp_serverowned "${MY_HTDOCSDIR}"/temp

	webapp_configfile "${MY_HTDOCSDIR}"/config/{db,main}.inc.php
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_postupgrade_txt en UPGRADING
	webapp_src_install
}